MACRO                                                          00050000
&NAME    STLINENO &LINE=,&LINELOC=,&MODE=OFF      PROTOTYPE             00100000
.********************************************************************** 00150000
.*                                                                    * 00200000
.* STATUS - CHANGE LEVEL 000                                          * 00250000
.*                                                                    * 00300000
.* NAME - STLINENO   (SET LINE NUMBER FOR NEXT TPUT EDIT TO 3270)     * 00350000
.*                                                                    * 00400000
.* FUNCTION - THE STLINENO MACRO IS USED TO SPECIFY ON WHICH LINE OF  * 00450000
.*            A TSO/VTAM DISPLAY SCREEN THE NEXT NON-FULL SCREEN TPUT * 00500000
.*            IS TO APPEAR.                                           * 00550000
.*                                                                    * 00600000
.*       THE MACRO PROTOTYPE IS ABOVE                                 * 00650000
.*                                                                    * 00700000
.*       THE STANDARD FORM OF THE EXPANSION IS BELOW                  * 00750000
.*                                                                    * 00800000
.*&NAME  LA    1,3                      PUT LINE NUM IN PARM REG      * 00850000
.*       LA    0,19                     LOAD ENTRY CODE               * 00900000
.*       SLL   0,24                     SHIFT TO HIGH ORDER BYTE      * 00950000
.*       SVC   94                       TERMINAL CONTROL MACRO SVC    * 01000000
.*                                                                    * 01050000
.********************************************************************** 01100000
         AIF   ('&LINE' NE '' AND '&LINELOC' NE '').ERROR1              01150000
         AIF   ('&LINE' EQ '' AND '&LINELOC' EQ '').ERROR2              01200000
         AIF   ('&MODE' NE 'OFF' AND '&MODE' NE 'ON').ERROR1            01250000
         AIF   ('&LINELOC' NE '').LNADDR                                01300000
         AIF   ('&LINE'(1,1) EQ '(').LNREG                              01350000
&NAME    LA    1,&LINE                  PUT LINE NUM IN PARM REG        01400000
         AGO   .STMODE                                                  01450000
.LNREG   ANOP                                                           01470000
&NAME    LR    1,&LINE(1)               PUT LINE NUM IN PARM REG        01500000
         AGO   .STMODE                                                  01550000
.LNADDR  ANOP                                                           01600000
         AIF   ('&LINELOC'(1,1) EQ '(').LNADREG                         01650000
&NAME    L     1,&LINELOC               PUT LINE NUM IN PARM REG        01700000
         AGO   .STMODE                                                  01750000
.LNADREG ANOP                                                           01800000
&NAME    L     1,0(,&LINELOC(1))        PUT LINE NUM IN PARM REG        01850000
.STMODE  ANOP                                                           01900000
         AIF   ('&MODE' EQ 'OFF').STMDOFF                               01950000
         LA    0,128                    PREPARE FLAY BYTE               02000000
         SLL   0,24                     SHIFT TO HIGH ORDER BYTE        02050000
         OR    1,0                      SET MODE=ON FLAG IN REG 1       02100000
         AGO   .ENTRYCD                                                 02110000
.STMDOFF ANOP                                                           02120000
         SR    0,0                      PREPARE FLAG BYTE               02130000
         OR    1,0                      SET MODE=OFF FLAG IN REG 1      02140000
.ENTRYCD ANOP                                                           02150000
         LA    0,19                     LOAD ENTRY CODE                 02200000
         SLL   0,24                     SHIFT TO HIGH ORDER BYTE        02250000
         SVC   94                       TERMINAL CONTROL MACRO SVC      02300000
         MEXIT                                                          02350000
.ERROR1  IHBERMAC 54,,,                                                 02400000
         MEXIT                                                          02450000
.ERROR2  IHBERMAC 24,,,                                                 02500000
         MEND                                                           02550000