MACRO                                                          00050040
&LABEL    RESUME &TCB=(4),&RB=(5),&RETURN=Y                             00250040
.********************************************************************** 00300040
.*        DECLARE LOCAL VARIABLES                                       00350040
.********************************************************************** 00400040
          LCLC    &OPERAND,&ERRFLG                                      00450040
.********************************************************************** 00500040
.*        VALIDITY CHECK PARAMETERS                                     00550040
.********************************************************************** 00600040
&ERRFLG   SETC    'OFF'                                                 00650040
&OPERAND  SETC    'TCB='                                                00700040
.*                                                                      00750040
          AIF (N'&TCB NE 1).ERROR                                       00800040
.RET1     ANOP                                                          00850040
&OPERAND  SETC    'RB='                                                 00900040
.*                                                                      00950040
          AIF (N'&RB NE 1).ERROR                                        01000040
.*                                                                      01050040
.RET2     ANOP                                                          01100040
&OPERAND  SETC  'RETURN='                                               01150040
          AIF (('&RETURN' NE 'Y') AND ('&RETURN' NE 'N')).ERROR         01200040
.*                                                                      01250040
.********************************************************************** 01300040
.*        GENERATE BAL CODE FOR TCB=                                    01350040
.********************************************************************** 01400040
          AIF  ('&ERRFLG' EQ 'ON').OUT                                  01450040
&LABEL   DS   0H                                                        01500040
          AIF  ('&TCB' EQ '(4)').RET4                                   01550040
          AIF  ('&TCB'(1,1) EQ '(').RET5                                01600040
.*        MUST BE  ADDRESS OF TCB                                       01650040
         L     4,&TCB             LOAD TCB ADDRESS                      01700040
          AGO   .RET4                                                   01750040
.*        TCB ADDRESS IS IN A REGISTER NOT 4                            01800040
.RET5     ANOP                                                          01850040
         LR    4,&TCB(1)          LOAD TCB ADDRESS                      01900040
          AGO   .RET4                                                   01950040
.********************************************************************** 02000040
.*        GENERATE BAL CODE FOR RB=                                     02050040
.********************************************************************** 02100040
.RET4    ANOP                                                           02150040
*                                 REGISTER 4 HAS TCB ADDRESS            02160040
         AIF   ('&RB' EQ '(5)').RET7                                    02180040
         AIF   ('&RB'(1,1) EQ '(').RET8                                 02250040
.*      MUST BE  ADDRESS OF RB                                          02300040
         L     5,&RB              LOAD RB ADDRESS                       02340040
         AGO    .RET7                                                   02380040
.*      RB ADDRESS IS IN A REGISTER NOT 5                               02420040
.RET8    ANOP                                                           02500040
         LR    5,&RB(1)           LOAD RB ADDRESS                       02550040
         AGO   .RET7                                                    02600040
.********************************************************************** 02650040
.*       GENERATE BAL CODE  FOR RETURN=                                 02700040
.********************************************************************** 02750040
.RET7    ANOP                                                           02800040
*                                 REGISTER 5 HAS RB ADDRESS             02820040
         AIF   ('&RETURN' EQ 'Y').RET10                                 02850040
         SLR   14,14              INDICATE  NO RETURN                   02900040
         L     15,FLCCVT-FLC(0,0) GET CVT ADDRESS                       02950040
         L     15,CVTRSUME-CVT(0,15)    GET ADDRESS OF RESUME           03050040
         BR    15                 GO TO ROUTINE                         03100040
.OUT     MEXIT                                                          03200040
.*       RETURN=Y                                                       03250040
.RET10   ANOP                                                           03300040
         L     15,FLCCVT-FLC(0,0) GET CVT ADDRESS                       03350040
         L     15,CVTRSUME-CVT(0,15)    GET ADDRESS OF RESUME           03450040
         BALR  14,15              GO TO ROUTINE, INDICATE RETURN        03500040
         MEXIT                                                          03600040
.********************************************************************** 03650040
.*       ERROR PROCESSING                                               03700040
.********************************************************************** 03750040
.ERROR   ANOP                                                           03800040
&ERRFLG  SETC  'ON'                                                     03850040
         IHBERMAC  1014,&OPERAND                                        03900040
         AIF   ('&OPERAND' EQ 'TCB=').RET1                              03950040
         AIF   ('&OPERAND' EQ 'RB=').RET2                               04000040
         MEND                                                           04050040